Tabulky Google lze použít k více než pouhému shromažďování a organizaci dat. Můžete jej také použít k určení aktuálního času, vytváření grafů a výpočtu věku pomocí data narození. Ten je objeven pomocí vzorců a funkcí zabudovaných přímo do Tabulek Google.
Postupujte podle tohoto článku a zjistěte, jak se to dělá.
Určení věku podle data narození v Tabulkách Google
Při používání Tabulek Google máte dva převládající způsoby, jak určit věk z data narození. Tady je DATEDIFcož je flexibilnější možnost, a YEARFRAC, jednodušší volba. Na konci článku byste měli být schopni určit nejen věk jednoho jedince, ale i více skupin různých lidí najednou.
Začneme funkcí DATEDIF.
Výpočet věku v Tabulkách Google pomocí funkce DATEDIF
Než se ponoříme do samotné funkce, musíme vědět, jak funguje. To bude vyžadovat naučení syntaxe pro použití s funkcí DATEDIF. Každá sekce, kterou jste zadali do funkce, koreluje s úkolem, podívejte se na tyto úkoly níže:
Syntax
=DATEDIF(počáteční_datum,koncové_datum,jednotka)
-
počáteční datum
- Výpočet bude muset začít datem narození.
-
datum ukončení
- Toto bude datum ukončení výpočtu. Při určování aktuálního věku bude toto číslo pravděpodobně dnešní datum.
- jednotka
- Volby výstupu, které se skládají z: „Y“, „M“, „D“, „YM“, „YD“ nebo „MD“.
-
Y – Celkový počet celých uplynulých let mezi zadanými počátečními a koncovými daty.
- YM – „M“ znamená měsíce. Tento výstup ukazuje počet měsíců následujících po plně uplynulých letech pro „Y“. Počet nepřesáhne 11.
- YD – „D“ znamená dny. Tento výstup ukazuje počet dní následujících po plně uplynulých letech pro „Y“. Počet nepřesáhne 364.
-
M – Celkový počet plně uplynulých měsíců mezi zadanými počátečními a koncovými daty.
- MD – Stejně jako v ostatních jednotkách, „D“ znamená dny. Tento výstup ukazuje počet dní následujících po úplně uplynulých měsících pro „M“. Nesmí překročit 30.
- D – Celkový počet zcela uplynulých dnů mezi zadanými počátečními a koncovými daty.
Výpočet
Nyní, když rozumíte syntaxi, která bude použita, můžeme nastavit vzorec. Jak již bylo uvedeno, funkce DATEDIF je flexibilnější možností při určování věku z data narození. Důvodem je to, že můžete vypočítat všechny podrobnosti o věku ve formátu roku, měsíce a dne.
Pro začátek budeme potřebovat příklad data, který použijeme v buňce. Budeme používat 14.7.1972 pro buňku A1. Uděláme vzorec v buňce napravo od ní, B1pokud chcete sledovat, abyste to pochopili.
Pro výpočet věku začneme nejzákladnější verzí vzorce. Pokud pomocí výše uvedené syntaxe zjistíte, co je co, A1 je technicky počáteční datum, dnes bude datum ukončenía věk v letech určíme pomocí “Y”. Proto bude první použitý vzorec vypadat takto:
=datedif(A1,today(),"Y")
Užitečný tip: Zkopírujte a vložte vzorec přímo do B2 a stiskněte Enter pro získání příslušného výstupu.
Když to uděláte správně, číslo udávající vypočítaný věk bude v B1 umístěno jako 46.
Udělejme stejný vzorec, ale tentokrát určíme věk v měsících pomocí “M” místo „Y“.
=datedif(A1,today(),"M")
Celkem by to bylo 559 měsíců. To je 559 měsíců staré.
Toto číslo je však trochu absurdní a myslím, že ho můžeme používáním výrazně snížit “YM” místo pouhého „M“.
=datedif(A1,today(),"YM")
Nový výsledek by měl být 7, což je mnohem lépe zvládnutelné číslo.
Abychom byli důkladní, podívejme se, jak budou vypadat dny s použitím „YD“ a „MD“.
=datedif(A1,today(),"YD")
=datedif(A1,today(),"MD")
Tentokrát jsou výsledky pro „YD“ zobrazeny v B1 a výsledek pro „MD“ se nachází v buňce B2.
Doteď jste to pochopili?
Dále je všechny spojíme dohromady ve snaze poskytnout si podrobnější výpočet. Zapisování vzorce může být trochu hektické, takže stačí zkopírovat a vložit poskytnutý vzorec do buňky B1.
Vzorec k použití je:
=datedif(A1,today(),"Y")&" Years "&datedif(A1,today(),"YM")&" months & "& datedif(A1,today(),"MD")&" days"
Ampersand se používá ke spojení každého vzorce dohromady jako řetězový článek. To je nezbytné pro získání úplného výpočtu. Vaše tabulka Google by měla obsahovat stejný vzorec jako:
Úplný podrobný výpočet nám poskytl 46 let 7 měsíců a 26 dní. Stejný vzorec můžete použít také pomocí funkce ArrayFormula. To znamená, že můžete vypočítat více než jen jedno datum, ale také více dat.
Náhodně jsme vybrali několik dat a zapojili je do dalších buněk A2-A5. Vyberte si svá vlastní data a užijte si s tím trochu zábavy. Chcete-li použít funkci ArrayFormula, zkopírujte a vložte následující do buňky B1:
=ArrayFormula(datedif(A1:A5,today(),"Y")&" Years "&datedif(A1:A5,today(),"YM")&" months & "& datedif(A1:A5,today(),"MD")&" days")
Toto jsou výsledky:
Nyní řekněme, že jste chtěli oddělit každou část data do vlastního úhledného malého sloupce kvůli organizaci. V Tabulkách Google přidejte počáteční_datum (datum narození) do jednoho sloupce a koncové datum do druhého. V mém příkladu jsme zvolili buňku B2 pro počáteční_datum a C2 pro koncové_datum. Moje data korelují s narozeními a nedávnými úmrtími celebrit Burta Reynoldse, Johnnyho Cashe a Luka Perryho.
Jak je znázorněno, sloupec A je jméno jednotlivce, sloupec B obsahuje počáteční_datum a C koncové_datum. Nyní přidáme další čtyři sloupce vpravo. Jeden pro každé „Y“, „YM“, „YD“ a kombinaci všech tří. Nyní stačí přidat správné vzorce do každého řádku pro každou celebritu.
Burt Reynolds:
=DATEDIF(B2,C2,"Y") Změňte „Y“ na odpovídající sloupec, který se pokoušíte vypočítat.
Johnny Cash:
=DATEDIF(B3,C3,"Y") Změňte „Y“ na odpovídající sloupec, který se pokoušíte vypočítat.
Luke Perry:
=DATEDIF(B4,C4,"Y") Změňte „Y“ na odpovídající sloupec, který se pokoušíte vypočítat.
Chcete-li získat vzorec JOINED, budete muset použít ArrayFormula stejně jako jsme to udělali dříve v článku. Můžete přidat slova jako let k označení výsledků za roky umístěním za vzorec a mezi závorky.
=ArrayFormula(datedif(B2,C2,"Y")&" Years "&datedif(B2,C2,"YM")&" months & "& datedif(B2,C2,"MD")&" days")
Výše uvedený vzorec platí pro celebritu. Pokud je však chcete všechny najednou vyřadit, zkopírujte a vložte následující vzorec do buňky G2:
=ArrayFormula(datedif(B2:B4,C2:C4,"Y")&" Years "&datedif(B2:B4,C2:C4,"YM")&" months & "& datedif(B2:B4,C2:C4,"MD")&" days")
Vaše tabulka Google by měla nakonec vypadat nějak takto:
Docela pěkné, co? Při použití funkce DATEDIF je to opravdu tak jednoduché. Nyní můžeme přejít k používání funkce YEARFRAC.
Výpočet věku v Tabulkách Google pomocí funkce YEARFRAC
Funkce YEARFRAC je jednoduchá pro jednoduché výsledky. Je to přímo k věci a poskytuje konečný výsledek bez všech dalších přidaných výstupů po roky, měsíce a dny.
Zde je základní vzorec, který lze použít pouze pro jednu buňku:
=int(YEARFRAC(A1,today()))
Do buňky A1 přidáte datum narození a vzorec pro výsledek vložíte do B1. Použijeme datum narození 11/04/1983:
Výsledkem je 35 let. Jednoduché, stejně jako při použití funkce DATEDIF pro jednu buňku. Odtud můžeme přejít k používání YEARFRAC v rámci ArrayFormula. Tento vzorec je pro vás užitečnější, když potřebujete vypočítat věk velkých skupin, jako jsou studenti, členové fakulty, členové týmu atd.
Budeme muset přidat sloupec s různými daty narození. K tomu použijeme sloupec B, protože A bude použito pro jména jednotlivců. Sloupec C bude použit pro konečné výsledky.
Abychom mohli vyplnit věk v sousedním sloupci, budeme muset použít následující vzorec:
=ArrayFormula(int(yearfrac(B2:B8,today(),1)))
Umístěte výše uvedený vzorec do buňky C2, abyste získali výsledky.
Pokud byste raději pokračovali celým sloupcem a nechtěli byste se obtěžovat zjišťováním, kde končí, můžete do vzorce přidat malou obměnu. Zaměřte se na IF a LEN směrem k začátku ArrayFormula takto:
=ArrayFormula(if(len(B2:B),(int(yearfrac(B2:B,today(),1))),))
Tím se vypočítají všechny výsledky v tomto sloupci počínaje B2.
Tabulky Google a data narození
Tabulky Google mají mnoho užitečných vestavěných funkcí, které lze použít k usnadnění života. Ať už jde o funkci rychlého sečtení hodnot do řádku/sloupce nebo o výpočet něčího věku, Tabulky Google vám pomohou.
